MOVEMENT
#3629
Content:
[ifelse([u(is.playing,%#)],
 {
  [ifelse([gt(u(moving),0)],
   {
    The party is already travelling in a direction: try after another [u(moving)] seconds.
   },
   [ifelse([not(u(is,u(party.mode),travelling))],
    [switch(u(party.mode),
     dungeon,
     {
      [u(dungeon.move,%#)]
     },
     camping,
     {
      The party is camping for another [u(camping)] seconds.
     },
     combat,
     {
      The party is engaged in combat. If you want to suggest a retreat then type [color(orange,black,retreat)].
     },
     {
      The party is indisposed and cannot plan movement right now.
     }
    )],
    [ifelse([u(can.move,%2,%3)],
     {
      [ifelse([u(is.leader,%#)],
       {
        [set(me,moving:5)][u(moving.by,%2,%3)]You lead the party %1.[oemit(%#,[u(char.name,%#)] leads the party %1. 
        [if(gt(u(voting),0),%rThe vote is cancelled.[set(me,voting:0)])])]
       },
       {
        [set(me,[name(%#)]_VOTE:%0)]     
        [if(eq(u(voting),0),set(me,voting:15))][set(me,voting.on:movement)]You suggest that the party move %1.[oemit(%#,[u(char.name,%#)] suggests that the party travel %1.)]  
       }
      )]
     },
     {
      The party cannot move in that direction.  
     }
    )]
   )]
  )]
 },
 {
   You need to provide a character for the Dungeon Master to recognize you as a player first. 
 }
)]

One line version:

[ifelse([u(is.playing,%#)],{[ifelse([gt(u(moving),0)],{The party is already travelling in a direction: try after another [u(moving)] seconds.},[ifelse([not(u(is,u(party.mode),travelling))],[switch(u(party.mode),dungeon,{[u(dungeon.move,%#)]},camping,{The party is camping for another [u(camping)] seconds.},combat,{The party is engaged in combat. If you want to suggest a retreat then type [color(orange,black,retreat)].},{The party is indisposed and cannot plan movement right now.})],[ifelse([u(can.move,%2,%3)],{[ifelse([u(is.leader,%#)],{[set(me,moving:5)][u(moving.by,%2,%3)]You lead the party %1.[oemit(%#,[u(char.name,%#)] leads the party %1. [if(gt(u(voting),0),%rThe vote is cancelled.[set(me,voting:0)])])]},{[set(me,[name(%#)]_VOTE:%0)]     [if(eq(u(voting),0),set(me,voting:15))][set(me,voting.on:movement)]You suggest that the party move %1.[oemit(%#,[u(char.name,%#)] suggests that the party travel %1.)]  })]},{The party cannot move in that direction.  })])])]},{You need to provide a character for the Dungeon Master to recognize you as a player first. })]